XML-Verarbeitung klappt nicht

[HelenInTrouble]

Hallo!

Ich versuche mit ActionScript eine XML-Datei auszulesen (was auch funktioniert) und zu verarbeiten. Leider liefert mir meine Klasse immer null als Wert.
Geb ich die Variable aber in der Klasse selbst aus, stimmt der Inhalt.
Woran liegt das?

Hier der Code der Klasse:

Code: Alles auswählen

package com {
       
    import flash.display.MovieClip;
    import flash.net.URLLoader;
    import flash.events.Event;
    import flash.net.URLRequest;       
       
    public class readXMLFile {
               
        private var contentXMLUrl:String = "myxml.xml";
        public var XMLContent:XMLList;
               
        public function readXMLFile() {
            var xmlLoader:URLLoader = new URLLoader();
            xmlLoader.addEventListener(Event.COMPLETE, XMLloaded);
            xmlLoader.load(new URLRequest(contentXMLUrl));
        }
               
        private function XMLloaded(e:Event):void {
            var XMLRes:XML = new XML(e.currentTarget.data);
            XMLRes.ignoreWhite = true;
            // nur Elementbaum mit "myElements"
            this.XMLContent = XMLRes.myElements;
            // gibt mir die XMLListe aus - das klappt hier
            trace(this.XMLContent);
        }               
    }       
}

So wird die Klasse aufgerufen:

Code: Alles auswählen

import com.readXMLFile;

var foo:readXMLFile = new readXMLFile();
// hier bekomme ich null als Wert
trace(foo.XMLContent);

Die Reihenfolge der Ausgaben ist auch so, dass das zweite trace() vor der Ausgabe in der Klasse ausgeführt wird.
Das zweite trace wird also ausgeführt bevor die Klasse die XML-Datei verarbeiten konnte.
Wie schaff ich, dass mir die XML-Liste ausserhalb der Klasse zur Verfügung steht? Wo liegt hier mein Fehler?

Danke und Grüße

[Ulli H.]

Ich würde mal stark vermuten, dass du da lediglich einen Pfadfehler hast. Allerdings kommt bei mir auch kein Wert in der Klasse



Kannst du auch mal die betreffende XML posten?

[HelenInTrouble]

Hi Ulli!

Also an der XML liegt es nicht. Ich krieg sie ja ausgegeben, nur halt nicht an der richtigen Stelle
Als Beispiel reicht

Code: Alles auswählen

<?xml version="1.0" encoding="utf-8"?>
    <playlist>
        <myElements name="first">
            <image>1.jpg</image>
        </myElements>
        <myElements name="second">
            <image>2.jpg</image>
        </myElements>
    </playlist>

Ich habe im Internet kein Beispiel gefunden welches so vorgeht wie ich es angefangen habe.
Sämtliche Beispiele arbeiten nachgeladene Dateien vollständig ab. Es gibt also nie einen Rückgabewert der ein nachgeladenes Element enthält. Eine andere Lösung habe ich nicht gefunden

Vllt. hast du noch eine Idee.

[Ravelution]

hi

hab änliches problem gehabt und folgendermaasen ist es gelöst worden

Code: Alles auswählen

package com {
    import flash.events.EventDispatcher;
    import flash.display.MovieClip;
    import flash.net.URLLoader;
    import flash.events.Event;
    import flash.net.URLRequest;       
       
    public class readXMLFile extends EventDispatcher {
               
        private var contentXMLUrl:String = "myxml.xml";
        public var XMLContent:XMLList;
               
        public function readXMLFile() {
            var xmlLoader:URLLoader = new URLLoader();
            xmlLoader.addEventListener(Event.COMPLETE, XMLloaded);
            xmlLoader.load(new URLRequest(contentXMLUrl));
        }
               
        private function XMLloaded(e:Event):void {
            var XMLRes:XML = new XML(e.currentTarget.data);
            XMLRes.ignoreWhite = true;
            // nur Elementbaum mit "myElements"
            this.XMLContent = XMLRes.myElements;
            // gibt mir die XMLListe aus - das klappt hier
            trace(this.XMLContent);
            dispatchEvent(new Event(Event.COMPLETE));
        }               
    }       
}


Die klasse liest alles ein aber dieses teil des codes kriegt es nicht mit wann es soweit bzw. vollständig eingelesen worden ist , deswegen auch müssen wir diesen event dispatchen, damit das ganze funktioniert unbedingt erben von EventDipatscher und natürlich die klasse importieren.
der aufruf selber sollte dann folgendermassen aussehen

Code: Alles auswählen

import com.readXMLFile;
var foo:readXMLFile = new readXMLFile();
foo.addEventListener(Event.COMPLETE,xmlComplete);

// hier bekomme ich null als Wert
function xmlComplete(e:Event):void {
        trace(foo.XMLContent);
}


ich hoffe, ich konnte weiter helfen
Ravelution

[HelenInTrouble]

Hey Ravelution!

Herzlichen Dank, klappt prima! Daran hab ich mir wirklich lange den Kopf zerbrochen.

Beste Grüße!